AS项目，或者Flash里：

stage.loaderInfo.parameters.tag

Flex3项目：

Application.application.parameters.tag

Flex4项目：

FlexGlobals.topLevelApplication.parameters.tag

备忘.

地址：

http://app.foxling.cn/picturelife/

功能：

• 鼠标拖动：左右滑动，向左滑动时，自动加载更多的照片（前提是还有更多照片…）
• 鼠标点击空白区域：缩放到合适大小
• 鼠标滚轮：放大，缩小显示区域
• 鼠标点击单张小图：加载该大图，并且放大到原始尺寸。

预览图：

预览图1

预览图2

后续：

仓促弄出来玩玩，有待继续改进。

自定义类

package skins
{
    import flash.display.GradientType;
    import flash.display.Graphics;

    import mx.skins.ProgrammaticSkin;

    public class CustomBG extends ProgrammaticSkin
    {

        public function CustomBG()
        {
            super();
        }

        override protected function updateDisplayList(w:Number, h:Number):void
        {
            super.updateDisplayList(w, h);

            var g:Graphics = graphics;
            var fillColors:Array = [0x191919,0x262626,0x191919];
            var fillAlphas:Array = [1.0,1.0,1.0];
            var fillRatios:Array = [0,127,255]

            g.clear();

            drawRoundRect(0, 0, w, h, 0, fillColors, fillAlphas,
                          horizontalGradientMatrix(0, 0, w, h), GradientType.LINEAR,fillRatios );
        }

        override public function get measuredWidth():Number
        {
            return 8;
        }

        override public function get measuredHeight():Number
        {
            return 8;
        }
    }

}

在CSS中使用ClassReference调用自定义类

.customBg
{
backgroundSize: “100%”;
backgroundImage: ClassReference(“skins.CustomBG”);
}

事件监听：

对父级对象加了监听函数，会造成内存泄露，例：

override protected function mouseDownHandler(…):void {
systemManager.addEventListener(“mouseUp”, mouseUpHandler);
......
}

解决：
在销毁对象的时候，remove掉这些监听，虽然弱引用也可以避免这些问题，但自己掌控感觉更好。

但以下几种情况不会造成内存泄露：

• 弱引用：someObject.addEventListener(MouseClick.CLICK, handlerFunction, false, 0, true);
• 对自己的引用：this.addEventListener(MouseClick.CLICK, handlerFunction);
• 子对象的引用：

  private var childObject:UIComponent = new UIComponent;
  addChild(childObject);
  childObject.addEventListener(MouseEvent.CLICK, clickHandler);
  

总之…有addEventListener，就removeEventListener一下吧，要为自己做的事负责~哈哈

清除引用

remove掉子对象后并不会删除该对象，他还保留在内存中，应该将引用设置为null

removeChildren(obj);
obj = null;

静态成员

Class （或MXML）中有：

public static var _eventService : MyService=new MyService();

解决：在dispose时，需要设置：

_eventService =null;

module (未解决)

moduleLoader unloadModule后
ModuleInfo 并不会被GC.
Garbage Collection in a MultiCore Modular Pipes Application
这篇文章介绍了一种GC策略，感觉对于ModuleInfo 的GC无效。
(未尝试、未遇到)

CSS样式

module 中如果使用了shell的CSS定义或是<mx:Style> 这样的定义，那么这个module将不能GC.
弹出的窗口应该是同样的结果.
解决方法，使用动态CSS文件
module init中

StyleManager.loadStyleDeclarations("css/myStyle.swf");

module dispose中

StyleManager.unloadStyleDeclarations("css/myStyle.swf");

TextInput/Textarea(未解决)

如果module中有window使用了TextInput/Textarea控件，不点击没有问题，只要点上去，那么很遗憾了，module和所在窗体将不能被GC.
这个BUG非常严重，目前还没有解决方法。
memory leak when using TextInput and TextArea when click the keyboard 这里面附加的解决方法无效。
通过profiler分析，应该和Focusmanager有关，只有一点击就不会释放。

CursorManager.setCursor

使用了

cursorID = CursorManager.setCursor(iconClosed);

dispose时要

CursorManager.removeCursor(cursorID); 

Bitmap

如果使用Bitmap，结束时需要调用其dispose方法，否则内存消耗巨大。
另外，BitmapData是可以共享使用的，多个Bitmap可以使用同一BitmapData，节省不少内存。

var bmp:Bitmap  =new Bitmap();

........

if (bmp.bitmapData!=null) {
    bmp.bitmapData.dispose();
}

Image

包含了Image对象时，在removeChildren时会造成不能释放（测试多次，结果不一，建议还是做如下处理）。
解决：

img.source = null;
this.removeChild(img);
img = null;

Loader、SWFLoader、声音、视频、Effect等…

• 如果是加载SWF文件，先停止播放。
• 停止声音的播放
• 停止正在播放的影片剪辑(Movieclip)
• 关闭任何连接的网络对象，例如Loader正在加载，要先close。
• 取消对摄像头或者麦克风的引用
• 取消事件监听器
• 停止任何正在运行的定时器，clearInterval()
• 停止任何Timer对象，timer.stop()
• 停止正在播放的效果(Effect)

其他

binding也疑似有memory leak 问题。

引用以及内存泄露相关博文和资料：
http://blogs.adobe.com/aharui/2007/03/garbage_collection_and_memory.html
http://www.craftymind.com/2008/04/09/kick-starting-the-garbage-collector-in-actionscript-3-with-air/
http://www.cnblogs.com/janyou/archive/2008/11/25/1340753.html
http://www.dreamingwell.com/articles/archives/2008/05/understanding_m.php

总结：由于之前Flash一直是在网页上使用，一般网页都是看完就关掉的，估计Adobe在内存回收这块也没有下太大的功夫，现在AIR的出现使得内存管理也相当重要了，并且，AIR本身对内存的消耗就相当大，一个没有任何内容的初始创建的AIR程序，就得占掉10-20M+的内存…AIR还需改善.

废话不多说，直接看代码，将需要记录的日志，比如出错信息记录到程序数据文件夹，以日期命名，便于追踪信息。

SWFObject是一个用于在HTML中方面插入Adobe Flash媒体资源（*.swf文件）的独立、敏捷的JavaScript模块。该模块中的JavaScript脚本能够自动检测PC、Mac机器上各种主流浏览器对Flash插件的支持情况。它使得插入Flash媒体资源尽量简捷、安全。而且它是非常符合搜索引擎优化的原则的。此外，它能够避免您的 HTML、XHTML中出现object、embed等非标准标签，从而符合更加标准。

SWFObject在IE下的BUG

如果Flash里绘制的对象的宽高是自适应Flash的宽高的，那么，使用SWFObject来插入Flash在IE会导致一个问题，当这个Flash被缓存后，也就是第二次访问该页面时，在该Swf文件被加载时，获取到的stage.stageWidth和stage.stageHeight为0，绘制的对象也就看不到了。

在Flash里监听resize事件，找出解决方法

如下(如果加载较慢就先等等吧~)：

用IE的话，会看到5行，有两次resize事件，这也就导致了Flash在加载的时候绘制对象错误(宽和高为0)：
数字是stage.stageWidth和stage.stageHeight

info
resize
0 x 0
resize
300 x 300

如果用Firefox等浏览器，只输出两行文字，没有resize事件：

info
300 x 300

AS里的解决方案

通过监听resize事件，当stage.stageWidth和stage.stageHeight大于0时再进行初始化

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;

    public class AutoSizeExample extends Sprite
    {
        private var txt:TextField;
        public function AutoSizeExample()
        {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            txt = new TextField();
            txt.multiline = true;
            txt.wordWrap = true;
            txt.text = "info\n";
            addChild(txt);

            if (stage.stageWidth>0 && stage.stageHeight>0){
                createChild();
            }else{
                stage.addEventListener(Event.RESIZE,onResize);
            }
        }

        private function onResize(e:Event):void
        {
            if (stage.stageWidth>0 && stage.stageHeight>0){
                stage.removeEventListener(Event.RESIZE,onResize); //删除事件监听
                createChild();
            }
            //否则继续监听事件，直到stage.stageWidth和stage.stageHeight大于0时才初始化
        }

        private function createChild():void
        {
            //进行初始化操作，创建各对象
            //.......................
            var w:Number = stage.stageWidth;
            var h:Number = stage.stageHeight;

            txt.appendText(w + " x " + h + "\n");
        }

    }
}

SWFObject.js里的解决方案

在swfobject.js里找到函数function createSWF(attObj, parObj, id)
里面针对winIE的处理方法是：el.outerHTML = '<object classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000"' + att + '>' + par + '</object>';
看了一下Adobe自己的AC_OETags.js，他是用document.write方法直接写入，没有这个问题；
直接写静态html(object)没有这种问题；
直接访问这个flash的地址，也没有这种问题。
至于el.outerHTML的方式为什么会导致这种问题，还没有深究，暂时还不太清楚是什么原因导致的~

待续~~~

单件模式的应用

从一个XML文件加载程序的基本配置信息，只需要在Flash初始化的时候或者Air程序启动的时候执行一次即可，并且，在程序的整个运行阶段都只需要一个实例，并不需要建多个实例或者读取多次XML。
例如：用一个xml文件保存AIR应用程序配置信息，里面包含窗口起始位置，窗口的宽高。

<setting>
	<window x="100" y="100" width="300" height="400">
</setting>

单件模式的实现

package cn.foxling.test
{
	public class Setting
	{
		private static var _instance:Setting;

		public function Setting(enforcer:SingletionEnforcer)
		{
		}

		public static function getInstance():Setting
		{
			if (Setting._instance == null) Setting._instance = new Setting(new SingletionEnforcer());
			return Setting._instance;
		}

	}
}

class SingletionEnforcer {}

单件模式必须具体的3个元素

• 私有静态属性，用于存储唯一实例
  private static var _instance:Setting;
• 公共静态方法，用于获取这个唯一实例，并且，在第一次执行时，创建这个唯一的实例
  public static function getInstance():Setting
• 为了限制类的多次实例化，通常使用私有构造函数，由于在AS3里面不支持私有构造函数，于是通过在一个文件中添加多个类的办法创建一个“私有”类(SingletionEnforcer类只能被该文件中的主类所访问)。

继续实现这个Setting类的功能

需要从XML文件加载程序的基本配置信息，给这个Setting类增加一些功能，比如读取配置，保存配置。
具体代码没有一一实现，把结构写了出来~

package cn.foxling.test
{
	import flash.events.EventDispatcher;

	public class Setting extends EventDispatcher
	{
		private static var _instance:Setting;

		private var _x:Number;
		private var _y:Number;
		private var _width:Number;
		private var _height:Number;

		public function Setting(enforcer:SingletionEnforcer)
		{}

		public static function getInstance():Setting
		{
			if (Setting._instance == null) Setting._instance = new Setting(new SingletionEnforcer());
			return Setting._instance;
		}

		public function loadXML():void
		{
			//通过URLLoader读取xml信息
			//派发加载成功的事件
		}

		public function save():void
		{
			//将_x,_y,_width,_height格式化成xml
			//并写入本地文件
			//派发保存成功的事件
		}

		//================================
		//为_x,_y,_width,_height写setter、getter方法
		//避免对_x,_y,_width,_height设置非法值
		//================================

	}
}

class SingletionEnforcer {}

版本更新

• 1.0 (2009-04-10)

Flex中的元标签列表如下：

[ArrayElementType]

使用ArrayElementType元数据标签可以让你定义数组元素的数据类型。

[ArrayElementType("Number")]
public var arr:Array;

事实上，MXML编译器只针对mxml代码中的ArrayElementType元数据标签的用法进行合理性检查。而对actionscript代码中的用法不进行合理性检查，通过试验可以知道，ArrayElementType标签此时是无效的。

也就是说，上面的声明是无效的~，只有在MXML里才能正确检查，你可以测试一下：

arr.push(1);
arr.push("name"); //并不会报错

Bindable绑定数据的例子

申明变量txt可绑定后，当txt值改变，绑定txt的Label显示的内容也会跟着改变。

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
layout="absolute" creationComplete="init()">
	<mx:Script>
		<![CDATA[
			[Bindable]
			private var txt:String = "Hello world.";

			private function init():void
			{
                            changeBtn.addEventListener(MouseEvent.CLICK,
                             function():void{txt="Hello World,Hello World."});
			}
		]]>
	</mx:Script>
	<mx:Label x="10" y="10" text="{txt}"/>
	<mx:Button x="10" y="36" label="更新数据" id="changeBtn"/>
</mx:Application>

[DefaultProperty("propertyName")]

DefaultProperty元数据标签用来将一个单一属性设定为某个类的默认属性。它允许在一个容器标签内设定属性，而不用定义属性的名字。

package myComponents
{
    import mx.controls.TextArea;

    // 定义一个默认的属性defaultText，下例中的Hello将做为defaultText的值。
    [DefaultProperty("defaultText")]

    public class TextAreaDefaultProp extends TextArea {

        public function TextAreaDefaultProp()
        {
            super();
        }       

        // Define a setter method to set the text property
        // to the value of the default property.
        public function set defaultText(value:String):void {
            if (value!=null)
            text=value;
        }

        public function get defaultText():String {
            return text;
        }
    }
}

在MXML里使用该组件：

<?xml version="1.0"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
    xmlns:MyComp="myComponents.*">
    <MyComp:TextAreaDefaultProp>Hello</MyComp:TextAreaDefaultProp>
</mx:Application>

更多信息以及例子请参阅：http://livedocs.adobe.com/flex/3/html/metadata_3.html

新的 Flash Player 10 中，需要上载或下载数据、操作系统剪贴板的操作等都需要用户参与，也就是说要实现类似的“复制”功能，必须要让用户点击指定的按钮或设置快捷键才可以解决。这也就意味着之前可以自动操作剪贴板的 Flash 脚本都已失效了。于是乎，开心网啊，校内啊，他们的复制按钮都失效啦，提示复制成功，粘贴后却还是之前的内容。

像Google相册、YouTube的链接都是点击选中，需要用户Ctrl+C自行复制的，这也是一种解决方案，好过开心网那种提示成功却没成功~~

既然操作剪贴板的功能需要用户参与，那还是有解决方案的，做一个Flash的按钮让用户点击复制~~~

演示如下：

代码：

<embed width="62" height="24" align="middle"
flashvars="txt=http://www.foxling.cn"
src="/examples/as3/Copy/Copy.swf"
quality="high" wmode="transparent"
allowscriptaccess="sameDomain"
pluginspage="http://www.adobe.com/go/getflashplayer"
type="application/x-shockwave-flash">

把需要复制的内容，通过FlashVars传给Flash，然后通过System类的setClipboard方法可以将需要的内容复制到剪贴板，flash.system.System是一个静态类，包含与发生在用户计算机上的某些操作相关的属性，如具有共享对象的操作、摄像头和麦克风的本地设置和剪贴板的使用。访问剪贴板的数据是被禁止的，所以，没有getClipboard的方法：

private function copy(e:MouseEvent):void
{
    var txt:String = LoaderInfo(root.loaderInfo).parameters.txt;
    System.setClipboard(txt);
    createText("已复制");
}

在AS3中，取得FlashVars参数的方法与以前不一样了，AS3用parameters 属性替换了ActionScript 1.0 和 2.0 提供 SWF 文件参数作为主时间轴的技术。

parameters是LoaderInfo对象的一个属性，对于加载的SWF等元素可以通过其Loader对像的contentLoaderInfo属性访问，由于SWF文件的主类的实例没有Loader对象，因此loaderInfo属性是访问SWF文件主类实例的LoaderInfo的唯一方法。

如果是Flex项目，可以通过Application.application.parameters.varname来访问FlashVars里的varname参数。

全部代码如下：

package {
	import flash.display.GradientType;
	import flash.display.LineScaleMode;
	import flash.display.LoaderInfo;
	import flash.display.Shape;
	import flash.display.SimpleButton;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.geom.Matrix;
	import flash.system.System;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;

	[SWF(width="62", height="24")]
	public class Copy extends Sprite
	{
		private var copyBtn:Sprite = new Sprite();
		private var btnText:TextField = new TextField();
		private const BTNWIDTH:Number = 60;
		private const BTNHEIGHT:Number = 22;

		public function Copy()
		{
			addChild(createButton());
		}

		private function createText(txt:String):void
		{
			var txtFormat:TextFormat = new TextFormat();
			txtFormat.align = TextFormatAlign.CENTER;
			btnText.text = txt;
			btnText.setTextFormat(txtFormat);
			btnText.width = BTNWIDTH;
			btnText.mouseEnabled = false;
			btnText.y = 2;
		}

		private function createButton():Sprite
		{
			createText("复制");

			var b:SimpleButton = new SimpleButton();
			b.upState = up();
			b.overState = over();
			b.downState = down();
			b.hitTestState = b.upState;
			b.addEventListener(MouseEvent.CLICK,copy);

			copyBtn.addChild(b);
			copyBtn.addChild(btnText);

			return copyBtn;
		}

		private function copy(e:MouseEvent):void
		{
			var txt:String = LoaderInfo(root.loaderInfo).parameters.txt;
			System.setClipboard(txt);
			createText("已复制");
		}

		private function up():Shape
		{
			return createShape([0xFFFFFF,0xCCCCCC]);
		}

		private function over():Shape
		{
			return createShape([0xFFFFFF,0xFFFFCC]);
		}

		private function down():Shape
		{
			return createShape([0xFFFFCC,0xFFFFFF]);
		}

		private function createShape(color:Array):Shape
		{
			var s:Shape = new Shape();
			var m:Matrix = new Matrix();
			m.createGradientBox(BTNWIDTH,BTNHEIGHT,-30,0,0);
			with(s.graphics){
				lineStyle(1,0xCCCCCC,1,false,LineScaleMode.NONE);
				beginGradientFill(GradientType.LINEAR,color,[1,1],[0,255],m);
				drawRoundRect(0,0,BTNWIDTH,BTNHEIGHT,5);
				endFill();
			}
			return s;
		}
	}
}

嗯~这个版本的缺点就是，要是用户禁用了Flash~~~